;;; -------------------------------------------------------------;;;
;;; Funkcja sprawdza czy w rysunku istnieje słownik o nazwie     ;;;
;;; [DictName]. Argument [Root] określa wskaznik słownika wlaści-;;;
;;; ciela. Zwraca T lun Nil                                      ;;;
;;;                                                              ;;;
(defun jk:DCT_isDict? (Root DictName)
  (if (dictsearch Root DictName) T nil)
)
;;; -------------------------------------------------------------;;;

;;; -------------------------------------------------------------;;;
;;; Funkcja tworzy słownik o nazwie [DictName]. Słownik zostanie ;;;
;;; utworzony w przypadku gdy nie istnieje już słownik o tej     ;;;
;;; nazwie. Jeżeli argument Msg? jest różny od nil i słownik już ;;;
;;; istnieje wyświetlane jest ostrzeżenie i funkcja zwraca nil.  ;;;
;;; gdy słownik zostanie utworzony zwracany jest wskaznik obiektu;;;
;;;                                                              ;;;
(defun jk:DCT_MakeDict (Root DictName Msg? / Test DictData NewDict)
  (setq Test (jk:DCT_isDict? Root DictName))
  (if Test
    (if Msg?
      (alert
	(strcat "Słownik o nazwie: "
		(strcase DictName)
		" jest już zdefiniowany."
	)
      )
      Nil
    )
    (progn
      (setq DictData
        (list '(0 . "DICTIONARY")'(100 . "AcDbDictionary")))
      (setq NewDict (entmakex dictData))
      (setq NewDict (dictadd Root DictName NewDict))
    )
  )
)

;;; -------------------------------------------------------------;;;
;;; Funkcja usuwa wpis do słownika [Root] o nazwie DictName.     ;;;
;;;                                                              ;;;
(defun jk:DCT_DelDict (Root DictName / Test DictList)
  (setq Test (jk:DCT_isDict? Root DictName))
  (if Test
    (progn
      (setq DictList (jk:DCT_DictList Root nil ))
      (if
	(dictremove Root DictName)
        (entdel (cdr (assoc DictName DictList)))
      )
    )
    Nil
  )
)