;; ----------------------------------------------------------------------------- ;
;; ODCZYT PLIKU TEKSTOWEGO                                                       ;
;; (1999) kojacek                                                                ;
;;                                                                               ;
;; Funkcja zwraca listę, łańcuch lub NIL                                         ;
;;                                                                               ;
;; Argumenty funkcji:                                                            ;
;; ===================                                                           ;
;;  CODE - gdy równe NIL funkcja zwraca listę łańcuchów tekstowych będących      ;
;;         liniami całego pliku. Gdy CODE różne od NIL (musi być typu INTEGER)   ;
;;         zwraca łańcuch tekstowy będący linią określoną przez ten argument.    ;
;;         (Uwaga: dla pierwszej linii CODE=0 dla drugiej 1 itd.)                ;
;;         Gdy INT jest większe niż ilość linii w pliku funkcja zwraca NIL       ;
;;  FILE - nazwa pliku - gdy bez scieżki dostępu plik poszukiwany jest na        ;
;;         standardowej ścieżce poszukiwań AutoCAD-a. Jeśli plik nie znajduje    ;
;;         się na tej ścieżce trzeba podać nazwę pliku wraz z pełną ścieżką      ;
;;         dostępu. W obu przypadkach gdy plik nie zostanie znaleziony,          ;
;;         wyświetlane jest okienko ostrzegawcze i funkcja zwraca NIL            ;
  (defun jk:SYS_Read-Files (CODE FILE / FLN FLD FDAT X)
    (setq FLN (findfile FILE))
    (if FLN
      (progn
        (if CODE
          (progn
            (setq FLD (open FLN "r"))
            (repeat CODE (read-line FLD))
            (setq FDAT (read-line FLD))
            (close FLD)
          )
          (progn
            (setq FLD (open FLN "r"))
            (while
              (setq X (read-line FLD))
              (setq FDAT
                (append FDAT
                (list X)
                )
              )
            )
            (close FLD)
          )
        )
      )
      (alert (strcat "Nie znaleziono pliku " FILE " "))
    )
    (if FDAT FDAT NIL)
  )
;; ----------------------------------------------------------------------------- ;

;; ----------------------------------------------------------------------------- ;
;; ODCZYT LINII PLIKU TEKSTOWEGO                                                 ;
;; (1999) kojacek                                                                ;
;;                                                                               ;
;; Funkcja zwraca łańcuch lub NIL                                                ;
;;                                                                               ;
;; Argumenty funkcji:                                                            ;
;; ===================                                                           ;
;;  CODE - gdy równe NIL funkcja zwraca łańcuch tekstowy będący linią pliku i    ;
;;         zawierający podany "klucz" (argument KEYN), w przeciwnym wypadku      ;
;;         (gdy CODE różne od NIL) zwraca następną linię. W przypadku gdy        ;
;;         KEYN nie istnieje funkcja zwraca NIL.                                 ;
;;         Gdy INT jest większe niż ilość linii w pliku funkcja zwraca NIL       ;
;;  FILE - nazwa pliku - gdy bez scieżki dostępu plik poszukiwany jest na        ;
;;         standardowej ścieżce poszukiwań AutoCAD-a. Jeśli plik nie znajduje    ;
;;         się na tej ścieżce trzeba podać nazwę pliku wraz z pełną ścieżką      ;
;;         dostępu. W obu przypadkach gdy plik nie zostanie znaleziony,          ;
;;         wyświetlane jest okienko ostrzegawcze i funkcja zwraca NIL            ;
;;  KEYN - "klucz" poszukiwań. Gdy w pliku występuje więcej odwołań do "klucza"  ;
;;         zwracane jest zawsze ostatnie napotkane wystąpienie.                  ;
;;         Rozpoznawane są duże i małe litery.                                   ;
  (defun jk:SYS_Read-Lines (CODE FILE KEYN / FLN FLD FDAT LEN BUF X)
    (setq LEN (strlen KEYN)
          FLN (findfile FILE)
    )
    (if FLN
      (progn
        (if CODE
          (progn
            (setq FLD (open FLN "r"))
            (while
              (setq BUF (read-line FLD))
              (if
                (= (substr BUF 1 LEN) KEYN)
                (setq FDAT BUF)
              )
            )
            (close FLD)
          )
          (progn
            (setq FLD (open FLN "r"))
            (while
              (setq BUF (read-line FLD))
              (if
                (= (substr BUF 1 LEN) KEYN)
                (setq FDAT (read-line FLD))
              )
            )
            (close FLD)
          )
        )
      )
      (alert (strcat "Nie znaleziono pliku " FILE " "))
    )
    (if FDAT FDAT NIL)
  )
;; ----------------------------------------------------------------------------- ;

;; ----------------------------------------------------------------------------- ;
;; PODZIAŁ ŁAŃCUCHA TEKSTOWEGO NA LISTĘ                                          ;
;;                                                                               ;
;; Funkcja rozbija łańcuch tekstowy na listę                                     ;
;; Autor: Bill Kramer - opublikowana w CADENCE 4/97                              ;
;;                                                                               ;
;; Argumenty funkcji:                                                            ;
;; ===================                                                           ;
;;  S - łańcuch tekstowy do podziału                                             ;
;;  D - lista separatorów (lista łańcuchów tekstowych)                           ;
;;                                                                               ;
;; Uwaga: Jeżeli w łańcuchu do rozbicia znajdują się liczby typu INT, funkcja    ;
;;        zwraca je jako REAL                                                    ;
  (defun S_PARSE (S D / BUF RES CNT CH DIGS ISNUM)
    (setq BUF ""
          CNT 1
          ISNUM 'T
          DIGS '("." "+" "-" "0" "1" "2" "3"
                 "4" "5" "6" "7" "8" "9"
                )
    )
    (repeat 
      (strlen S)
      (setq CH (substr S CNT 1)
            CNT (1+ CNT)
      )
      (cond
        ((and 
           (member CH D)
           (> (strlen BUF) 0)
         )
         (setq RES
         (cons
           (if ISNUM
             (atof BUF)
             BUF
           )
           RES
          )
             BUF ""
             ISNUM 'T
         )
        )
        ((not (member CH D))
          (setq BUF (strcat BUF CH))
          (if 
            (null (member CH DIGS))
            (setq ISNUM NIL)
         )
       )
     )
   )
   (if 
     (> (strlen BUF) 0)
     (setq RES
       (cons
         (if 
           ISNUM
           (atof BUF)
           BUF
         )
         RES
       )
     )
   )
   (reverse RES)
 )
;; ----------------------------------------------------------------------------- ;